Đo đạc & hiển thị kết quả trực tiếp lên đồ thị Excel

Nhằm mục đích giao tiếp, đoạn code sau đây mô tả 1 ví dụ đơn giản sử dụng Arduino Uno 3 để đọc dữ liệu nhiệt độ và độ ẩm trên 2 cảm biến DHT22 và DHT11 và gửi các dữ liệu này về máy tính thông qua cổng giao tiếp USB. Các cảm biến được bố trí cắm thẳng vào Arduino.

#include "DHT.h" 	// Thư viện cho cảm biến DHT
int DHT1Type = DHT22; 	// Loại cảm biến DHT22
int DHT1_Data = 11; 	// Pin Data kết nối với chân 11
int DHT1_GND = 13; 	// Pin GND kết nối với chân 13
int DHT1_VCC = 12; 	// Pin VCC kết nối với chân 12
int DHT2Type = DHT11; 	// Loại cảm biến DHT11
int DHT2_Data = 3; 	// Pin Data kết nối với chân 3
int DHT2_GND = 2; 	// Pin GND kết nối với chân 2
int DHT2_VCC = 4; 	// Pin VCC kết nối với chân 4

float t1 = 0; 		// Các biến dùng để chứa dữ liệu nhiệt độ & độ ẩm
float h1 = 0;
float t2 = 0;
float h2 = 0;
int Count = 0; 		// Biến Count dùng để xác định số bộ dữ liệu gửi trong 1 vòng

DHT dht1(DHT1_Data, DHT1Type); 		// Khai báo các cảm biến DHT
DHT dht2(DHT2_Data, DHT2Type); 		//

void setup()
{
    pinMode(DHT1_GND, OUTPUT); 		// Set & connect Pin_GND của DHT1 = GND
    digitalWrite(DHT1_GND, LOW);
    pinMode(DHT1_VCC, OUTPUT); 		// Set & connect Pin_VCC của DHT1 = 5V
    digitalWrite(DHT1_VCC, HIGH);
    pinMode(DHT2_GND, OUTPUT); 		// Set & connect Pin_GND của DHT2 = GND
    digitalWrite(DHT2_GND, LOW);
    pinMode(DHT2_VCC, OUTPUT); 		// Set & connect Pin_VCC của DHT2 = 5V
    digitalWrite(DHT2_VCC, HIGH);

    dht1.begin(); 			// Khởi động cảm biến DHT22
    dht2.begin(); 			// Khởi động cảm biến DHT11
    Serial.begin(128000);
    Serial.println("CLEARDATA"); 	// xóa dữ liệu trên sheet đầu tiên của file excel
    Serial.println("LABEL,Time,Temp 1 (oC),Humid 1 (%RH),Temp 2 (oC),Humid 2 (%RH)"); // Nhãn (label) cho 5 cột đầu tiên trên sheet đầu tiên của file excel
}
void loop()	{
    Count++;
    Serial.print("DATA,TIME,"); 	// Gán giá trị cho cột đầu tiên = thời gian hiện hành
    t1 = dht1.readTemperature(); 	// Đọc nhiệt độ trên DHT1
    Serial.print(t1); 			// giá trị cho cột thứ 2
    Serial.print(","); 			// chuyển sang cột tiếp theo
    h1 = dht1.readHumidity(); 		// Đọc độ ẩm tren DHT1
    Serial.print(h1); 			// giá trị cho cột thứ 3
    Serial.print(","); 			// chuyển sang cột tiếp theo
    t2 = dht2.readTemperature(); 
    Serial.print(t2); 
    Serial.print(","); 
    h2 = dht2.readHumidity(); 
    Serial.println(h2); 
    if (Count >= 43200) { 		// giới hạn số bộ dữ liệu trong 43200 lần gửi, sau đó lặp lại & lưu chồng lên dữ liệu cũ
        Count = 0;
        Serial.println("ROW,SET,2"); 	// Bắt đầu từ Row 2 của sheet Excel    
    }
    delay(2000); 			// Quyết định tần suất đọc & gửi dữ liệu
}

Với đoạn code này, ta chỉ cần cắm  DHT11 vào chân 2-4 và DHT22 vào chân 11-13 như hình chụp dưới đây.