Phương pháp Charlieplexing và LoLShield VU Meter

I. GIỚI THIỆU

Charlieplexing đã được đề xuất vào đầu năm 1995 bởi Charlie Allen tại Maxim Integrated. Tuy nhiên, phương pháp này đã được biết đến và sử dụng trong những năm 1980 và được mô tả chi tiết vào năm 1979 trong một bằng sáng chế của Christopher W. Malinowski, Heinz Rinderle, và Martin Siegle thuộc Bộ Nghiên cứu và Phát triển, AEG-Telefunken, Heilbronn, Đức với tên gọi là "Hệ thống tín hiệu ba trạng thái".Nguồn tham khảo: https://en.wikipedia.org/wiki/Charlieplexing

Theo Charliplexing, ta có mối liên hệ giữa số lượng PINs vi điều khiển và số lượng LEDs cần điều khiển như sau:

Xét trường hợp dùng 3 PINs để điều khiển 6 LEDs:

Chúng ta chú ý về ba trạng thái của chân Arduino là: "high" (5V), "low" (0V) và "input".  Chế độ "input" đặt chân Arduino ở trạng thái tổng trở cao (high-impedance state). Xem thêm tại link: https://www.arduino.cc/en/Tutorial/DigitalPins

II. CHUẨN BỊ

List vật tư chuẩn bị theo bảng bên dưới:

III. PHẦN CỨNG

Tham khảo từ Jimmie P Rodgers: https://github.com/jprodgers/LoLshield, bao gồm bản vẽ Eagle, thư viện LoLShield và các chương trình test.

3.1. SƠ ĐỒ NGUYÊN LÝ

3.2. MẠCH IN

Khi làm mạch in 2 mặt, các bạn có thể tham khảo trên internet, có rất nhiều link hướng dẫn chi tiết.

• Mạch in Top, Bottom theo hình bên dưới

• Hình thực tế board LoLShield

Lưu ý

Khi hàn đèn LED, chúng ta nên làm theo từng hàng (từ hàng 1 đến hàng 9, mỗi hàng có 14 led) theo thứ tự lớp Bottom trước và lớp Top sau. Nếu ta hàn nhiều hàng (hay cột) cùng một lúc thì rất khó để kiểm tra LED hỏng hay chạm chập…. Sau khi hàn xong từng hàng, chúng ta add thư viện của LoLShield & dùng chương trình sau để test từng hàng LED:

#include "Charliplexing.h"
int ad=50; // Delay có thể thay đổi
void setup()
{
  LedSign::Init();  // Khởi động LoLShield
}
void loop()
{
  for (int x=0; x<14; x++)
  {
    for (int y=0; y<9; y++)
    {
      LedSign::Set(x,y,1); // Bật LED tại vị trí x,y
      delay(ad);
    }
  }
  delay(1000);
  for (int x=0; x<14; x++)
  {
    for (int y=0; y<9; y++)
    {
      LedSign::Set(x,y,0); // Tắt LED tại vị trí x,y
      delay(ad);
    }
  }
  delay(1000);
}

Ví dụ:

• Để test 14 LED hàng 1, ở vòng lặp: for (int y=0; y<9; y++), ta thay thế bằng for (int y=0; y<1; y++). LED nào không sáng theo thứ tự hoặc tắt theo thứ tự, chúng ta phải kiểm tra và fix nó trước khi hàn 14 LED ở hàng mới.
• Để test 28 LED hàng 1 & hàng 2, ta thay thế bằng for (int y=0; y<2; y++)
• ….Cứ thế cho đến hết 9 hàng: (int y=0; y<9; y++)
• Xem tại Video bên dưới: LoLShield - First Test.

IV. CHƯƠNG TRÌNH

Mình sẽ dùng LoLShield để làm VU Meter bằng biến đổi FFT. VU meter này kết nối trực tiếp đến laptop/desktop, mobile phone, tablet hay các thiết bị chơi nhạc khác qua jack 3.5mm.

4.1. TÌM HIỂU FFT

a. Tham khảo FFT

Các bạn có thể tham khảo FFT tại các trang:

• https://en.wikipedia.org/wiki/Fast_Fourier_transform
• https://vi.wikipedia.org/wiki/Bi%E1%BA%BFn_%C4%91%E1%BB%95i_Fourier_nhanh

b. FFT dùng Microsoft Excel

Cách cài đặt và phân tích FFT, ở đây mình dùng bản Microsoft Excel 2010:

• Cách cài đặt Analysis Toolpak: https://technet.microsoft.com/en-us/library/ff969363.aspx
• Các hàm phân tích trong Analysis Toolpak trong đó có hàm Fourier Analysis: https://support.office.com/en-us/article/Use-the-Analysis-ToolPak-to-perform-complex-data-analysis-6c67ccf0-f4a9-487c-8dec-bdb5a2cefab6

c. Mô phỏng FFT bằng Microsoft Excel 2010

• Dạng sóng ở miền thời gian.
  • VD: Chúng ta muốn phân tích một tín hiệu bao gồm 3 thành phần như sau:

Ở miền thời gian, tín hiệu này có dạng:

• Ở miền tần số, ta cài đặt các thông số sau

Các lưu ý:

• Tần số lấy mẫu (Sampling frequency): 10,000. Tại sao lại chọn là 10,000 ? Vì hàm analogRead() cần 100us cho một lần lấy mẫu, hay trong 1s Arduino Uno có thể đọc 10,000 lần.???. Xem link: http://arduino.vn/reference/analogread.
• Sampling frequency =1/Sampling_interval (1/100 us).
• Frequency ratio sampling/signal = 200, có nghĩa với tín hiệu 50Hz, nó sẽ lấy mẫu được 200 lần trong một chu kỳ, với 1,000Hz sẽ là 10 lần và 2,000Hz sẽ là 5 lần.

​Xem Chart bên dưới:

Dùng Analysis Toolpak trong Excel 2010, ta sẽ được bảng tính như sau:

Cuối cùng, chúng ta có được biến đổi FFT cho tín hiệu trên bằng cách vẽ Amplitude theo trục y và FFT Freq. theo trục x. Lưu ý ở cột FFT Output Range, dạng số a+b*i là số phức.

d. Thư viện FFT cho Arduino

• Link cho thư viện fix_fft: https://github.com/imagest108/arduino/tree/master/libraries/FixFFT
• Tác giả của thư viện fix_fft: http://forum.arduino.cc/index.php?topic=38153.0

4.2. CHƯƠNG TRÌNH VU METER CHO LOLSHIELD

Tham khảo từ trang: http://andydoro.com/vulol/ của Andy Doro. Các bạn xem Video thực tế bên dưới: LoLShield - FFT VU METER.

/*
FFT for LoL Shield
 by Andy Doro
 http://andydoro.com/vulol/
 based on FFT library and code from the Arduino forums and
 the Charlieplexing library for the LoL Shield.
 */
// include libraries
#include "Charliplexing.h"
#include "fix_fft.h"
// where we read the audio voltage
#define AUDIOPIN 0
char im[128], data[128];
char data_avgs[14];
int i=0,val;
void setup() {
  LedSign::Init();            // initilizes the LoL Shield
}
void loop() {

  for (i=0; i < 128; i++){                                     
    val = analogRead(AUDIOPIN); // read voltage                                    
    data[i] = val;                                       
    im[i] = 0;                                                     
  };
  fix_fft(data,im,7,0);
  for (i=0; i< 64;i++){                                      
    data[i] = sqrt(data[i] * data[i] + im[i] * im[i]);  // this gets the absolute value of the values in the array, so we're only dealing with positive numbers
  };     
  // average bars together
  for (i=0; i<14; i++) {
    data_avgs[i] = data[i*4] + data[i*4 + 1] + data[i*4 + 2] + data[i*4 + 3];   // average together 
    data_avgs[i] = map(data_avgs[i], 0, 20, 0, 9);                              // remap values for LoL
  }
  // set LoLShield
  for (int x=0; x < 14; x++) {
    for (int y=0; y < 9; y++) {
      if (y < data_avgs[13-x]) { // 13-x reverses the bars so low to high frequences are represented from left to right.
        LedSign::Set(x,y,1);        // set the LED on
      } 
      else {
        LedSign::Set(x,y,0);       // set the LED off
      }
    } 
  }
}

V. PHẦN KẾT

• Về thư viện fix_fft, các bạn có thể kiểm tra độ chính xác thông qua bảng LED ma trận với kích cỡ khoảng WxH = 64x128 kết hợp với các phần mềm Tone/ Frequency Generator, chẳng hạn như: http://onlinetonegenerator.com/
• Mục đích bài viết cũng để chia sẻ các Tool Data Analysis phân tích dữ liệu rất hay của Microsoft Excel. Ngoài Fourier Analysis, còn có công cụ khác như Histogram rất hữu ích trong việc phân tích, báo cáo trong công việc.
• Bài viết khá dài và trình bày có phẩn lủng củng. Mình rất mong nhận được ý kiến đóng góp của các bạn trong Cộng đồng Arduino Việt Nam.