Hướng dẫn điều khiển động cơ bước với thư viện Accel Stepper và driver điều khiển động cơ bước A4988 hoặc DRV8825

Có rất nhiều tài liệu trên mạng nói về động cơ bước. Bạn có thể google để tìm ra nó. Tuy nhiên, mình xin đề xuất cho các bạn một số tài liệu sau để tham khảo.

• Động cơ bước trên Wikipedia
• Động cơ bước trên Google

Nôm na, động cơ bước là một loại động cơ mà ở đó bạn sẽ có thể quy định chính xác số góc quay và động cơ bước sẽ phải quay. Không giống như Servo, động cơ bước có thể quay bao nhiêu độ tùy ý và mỗi lần quay nó sẽ quay được 1 step, 1 step ở đây là bao nhiêu còn phụ thuộc vào động cơ bước của bạn. Ví dụ, động cơ bước của bạn có 72 step thì nó sẽ cần quay 72 step để hoàn thành một vòng quay. Số step này là hằng số, nhưng bạn có thể dùng công nghệ micro step để "cải thiện" số vòng quay động cơ bước của bạn.

• Arduino UNO hoặc mạch Arudino nào cũng được ha.
• Driver điều khiển động cơ A4988 hoặc DRV8825.
• Breadboard
• Nguồn cấp 12V (tối thiểu 1A).
• Dây breadboard.

Bạn nạp đoạn code sau cho Arduino.

// Run a A4998 Stepstick from an Arduino UNO.
// Paul Hurley Aug 2015 - http://www.instructables.com/id/Drive-a-Stepper-Motor-with-an-Arduino-and-a-A4988-/
int x; 
#define BAUD (9600)


void setup() 
{
  Serial.begin(BAUD);
  pinMode(6,OUTPUT); // Enable pin - chân khởi động - nối vào GND sẽ giúp ta bật động cơ bước, nối vô VCC động cơ bước được thả ra. Nôm na: GND = servo.attach, VCC = servo.detach
  pinMode(5,OUTPUT); // Step pin
  pinMode(4,OUTPUT); // Dir - pin
  digitalWrite(6,LOW); // Set Enable low
}

void loop() 
{
  digitalWrite(6,LOW); // Đặt Enable ở trạng thái LOW
  digitalWrite(4,HIGH); // Đặt Dir  ở trạng thái HIGH
  Serial.println("Cho chay 200 steps (1 vong)");
  for(x = 0; x < 200; x++) // Cho chay 1 vong
  {
    digitalWrite(5,HIGH); // Output high
    delay(10); // chờ
    digitalWrite(5,LOW); // Output low
    delay(100); // chờ
  }
  Serial.println("Pause");
  delay(1000); // dừng 1 s rồi quay tiếp
}

Nhớ gắn điện 12V vô nha

Nếu là một người thích sự hoàn hảo thì khi bạn nhìn vào code trên thì sẽ thấy cần rất nhiều dòng code chỉ để làm 1 động cơ bước hoạt động, và với những dòng delay như vậy thì chắc hẳn, bạn sẽ hiểu rằng, chả có cách nào chạy những tiến trình khác khi động cơ bước đang chạy. 

Arduino có hỗ trợ sẵn bộ thư viện stepper trong file example. Nhưng nếu bạn đã từng thử thì hẳn biết một điều là, thư viện đó cũng delay như code kia. Nghĩa là trong quá trình động cơ bước hoạt động thì cả chương trình sẽ phải dừng đợi nó hoạt động theo (cơ chế này gọi là cơ chế đồng bộ - sync).

Để điều khiển được nhiều động cơ bước thì chúng ta phải biết ngõ xử lý bất đồng bộ, nghĩa là sao? Nghĩa là phải biết thay hàm delay bằng cách khác, và đó chính là dùng timer, chính là dùng hàm millis(). Và ý tưởng đó đã được thể hiện trong thư viện AccelStepper, thư viện này đã ứng dụng nguyên lý xử lý bất đồng bộ (async) để làm nên nó - một thư viện cực kì hữu ích!

Để tài về thư viện này, các bạn hãy click vào đây (mirror).

Và đây là đoạn code mẫu của thư viện này.

Bạn nhớ nối Enable xuống GND nhé .

#include <AccelStepper.h>
AccelStepper stepper(1,5,4);// pin 5 step, pin 4 dir

void setup() {
  Serial.begin(9600);
  pinMode(6,OUTPUT); // Enable
  digitalWrite(6,LOW); // Dặt Enable xuống low để khởi động động cơ
}

void loop() {
  if (stepper.distanceToGo() == 0)  //kiểm tra thử động cơ bước có còn đang chạy hay không, nếu không còn chạy thì...
  {  
    delay(1000);
    stepper.moveTo(rand() % 400); //chuyển đến tọa độ 0 - 399 (Random)
    stepper.setMaxSpeed((rand() % 400) + 200);  //chỉnh tốc độ. 
    stepper.setAcceleration((rand() % 200) + 100); //chỉnh gia tốc.
    //kiến thức về tốc độ và gia tốc là kiến thức cơ bản vật lý lớp 10, vì vậy, các bạn lớp 9 trở xuống muốn dùng động cơ bước thì nhớ tìm hiểu khái niệm này nhé. hehe
  }

  Serial.println(stepper.distanceToGo());
  stepper.run();  // phải có hàm này ở hàm loop với mỗi biến stepper thì nói mới chạy được
}