HƯỚNG DẪN SỬ DỤNG INUT CẢM BIẾN ĐỂ ĐIỀU KHIỂN 8 RELAY QUA INTERNET (KHÔNG CẦN INUT NODE - RED IDE)

Bạn có một DỰ ÁN hay giống thế này? Chia sẻ nhé!

Dzn gửi vào Thứ năm, 20 Tháng 6, 2019 - 13:34

16311 lượt xem

Mô Tả Dự Án

Để điều khiển 8 relay qua internet với iNut cảm biến, trước giờ muốn thực hiện được việc này các bạn cần phải sử dụng iNut Node - RED IDE để điều khiển nó, đôi khi cũng bất tiện cho một số bạn newbie vì phải thực hiện qua quá nhiều bước vừa trên máy tính vừa trên điện thoại. Hoặc nhưng bạn master thì sẽ sử dụng bộ API có sẵn của iNut Platform để tự làm app riêng cho mình. Hôm nay, mình sẽ hướng dẫn bạn cách sử dụng APP INUT để điều khiển 8 relay từ xa qua internet mà không cần iNut Node - RED IDE.

Giờ chúng ta sẽ bắt đầu làm nó luôn nha.

I. Bạn Cần Chuẩn Bị Những Gì?

Phần Cứng

iNut Cảm Biến
Arduino (mình xài uno)
USB Type B
Module 8 relay (ở đây mình không có module 8 relay nên mình xài 2 module 4 relay nha)
Một ít dây bus cái - cái để cắm, rào đựng hàn lên iNut Cảm Biến

Sơ đồ Kết Nối

Module 4 Relay 1	Module 4 Relay 2	iNut Cảm Biến
VCC	VCC	5V
GND	GND	GND
IN1		2
IN2		3
IN3		4
IN4		5
	IN1	6
	IN2	7
	IN3	8
	IN4	9

Phần Mềm

Trên điện thoại di động:
- iNut - Platform (các bạn search trong apple store hoặc google play từ khóa inut là ra). Tải về trên Apple Store, tải về ở Google Play.
Trên máy tính:
- Git
- NodeJS (mirror)

Các bạn đọc bài viết này để biết cần chuẩn bị những phần mềm gì: http://arduino.vn/cc

II. Lập Trình:

Bạn Cần Chuẩn Bị Thư Viện Cho iNut Cảm Biến Cho Arduino : https://github.com/ngohuynhngockhanh... (tải nhanh)

Code Arduino


#include <iNut.h>
iNut sensor;

#define BAT LOW
#define TAT HIGH
#define RELAY_COUNT 8
#define WRITE_COMMAND 200
int relay[] = {2,3,4,5,6,7,8,9};
void setup() {
  Serial.begin(9600); //bật baudrate ở mức 9600

  Serial.println("San sang nhan lenh");

  for (int i = 0; i < RELAY_COUNT; i++) {
    pinMode(relay[i], OUTPUT);
    digitalWrite(relay[i], TAT);
  }
  
  //Khai báo số lượng luồn cảm biến
  sensor.setup(8); //Sẽ có 08 luồn cảm biến

  sensor.addCommand("ON", onFunction);
  sensor.addCommand("OFF", offFunction);
  sensor.addCommand("ONLINE", onlineFunction);
  sensor.addCommand("OFFLINE", offlineFunction);
  sensor.addCommand("TIME", timeFunction);
  sensor.setDefaultHandler(defaultHandler);
}
void timeFunction() {
  int year = atoi(sensor.next());
  int month = atoi(sensor.next());
  int day = atoi(sensor.next());
  int hour = atoi(sensor.next());
  int minute = atoi(sensor.next());
  int second = atoi(sensor.next());
  Serial.print("Bay gio la: ");
  Serial.print(year);
  Serial.print('/');
  Serial.print(month);
  Serial.print('/');
  Serial.print(day);
  Serial.print(' ');
  Serial.print(hour);
  Serial.print(':');
  Serial.print(minute);
  Serial.print(':');
  Serial.print(second);
  Serial.println('!');
}

void onlineFunction() {
  Serial.println("Thiet bi dang ket noi Internet rat ok");
}

void offlineFunction() {
  Serial.println("Thiet bi dang mat ket noi");
}

void onFunction() {
  
  int bit_index = atoi(sensor.next()) - WRITE_COMMAND;
  
  Serial.print("Bat relay thu ");
  Serial.println(bit_index);
  
  digitalWrite(relay[bit_index],BAT);
}

void offFunction() {
  int bit_index = atoi(sensor.next())  - WRITE_COMMAND;
  Serial.print("Tat relay thu ");
  Serial.println(bit_index);
  digitalWrite(relay[bit_index], TAT);
}

void loop() {

  //sensor.setValue(0, digitalRead(LED)); //đọc giá trị của đèn LED

  for (int i = 0; i < RELAY_COUNT; i++) {
    int value = digitalRead(relay[i]);
    //đồng bộ trạng thái iNut
    if (value == BAT) {
      sensor.turnOn(0, i); 
    } else {
      sensor.turnOff(0, i); 
    }
  }
  
  //giá trị cho các luồn từ 1-7 là giá trị random
  ///Tại sao lại sử dụng random? Vì đây là thử nghiệm, bạn có thể thay thế giá trị random bằng một giá trị cảm biến hoặc trị số mà bạn mong muốn đồng bộ lên Internet!
  for (byte i = 1; i <= 7; i++) {
    unsigned long value = random() % 10000; //trả về giá trị random - "hên xui" - tự do
    sensor.setValue(i, value); //gán giá trị trên vào luồn
  }
  sensor.loop();
}

//Nếu nhận được lệnh không phải từ những lệnh được đăng ký trước thì sẽ ghi ra ở đây
void defaultHandler(const char *command) {
  Serial.print(F("---Not found handler: "));
  Serial.println(command);


  //Đoạn chương trình dưới chỉ dùng để debug, để các bạn biết chương trình của mình ở lỗi ở đâu để khắc phục, cũng không cần hiểu nha.
  int idx = 0;
  char *arg;
  while ((arg = sensor.next()) != NULL) { //còn tham số nào thì in ra
    Serial.print("-----> Gia tri thu #");
    Serial.print(idx);
    Serial.print(": ");
    Serial.println(arg);
   
    idx++;
  }
}